
A. Model tested

B. Retrodictive Checks:
Retrodictive checks provide a way of assessing model adequacy. From the perspective of narratively generative modeling, the goal is to build a model that captures how the data were generated. When a model is inadequate, it misses key aspects of this narratively generative process. Retrodictive checks provide a way to assess this by simulating data from the fitted model and then comparing summaries of those simulations to summaries of the actual observations. For Likert data, natural summaries are the counts of each level of the ordered response. These counts can be visualized in a histogram, as shown below, where the black line indicates the counts for each category of the Likert item and the blue shades indicate quantiles of the simulations from the model (10% - 90% quantiles, with darker shades indicating higher probability regions). The goal is not to ensure that the simulations overlap the black line for every single category for every item. Instead, the goal is to assess egregious misfit that then suggests some additional incorporation of domain expertise. Critically, domain expertise must inform the subsequent modifications to the model, otherwise it simply becomes a curve fitting exercise.
Below is an example of how retrodictive checks were used in this analysis. After visual inspection, we saw noticeable retrodictive tension, where the model strongly underestimates highest category responses for females and overestimates them for males. These checks prompted the authors to include varying cutpoint parameters by sex, which in hindsight, makes sense for the items in our study. The subsequent retrodictive checks for the update model no longer expressed this inadequacy.
Retrodictive check plots for all items included in this analysis are shown below. Females are odd item numbers and males are even item numbers in the plots below. Items are ordered consecutively, WHODAS 1-5, bIPF 1-4, and QLS 3-7,13. 
WHODAS

B-IPF

QLS

C. Stan Code
// x refers to WHODAS, y to bIPF, and z to QLS

functions {
  vector make_cutpoints(vector probabilities, int ncuts) {
    vector[ncuts] cutpoints;
    real running_sum = 0;
      for (n in 1:ncuts) {
        running_sum += probabilities[n];
        cutpoints[n] = inv_Phi(running_sum);
      }
    return cutpoints;
  }
}
data {
  int<lower=1> N;  
  int<lower=1> N_obs_x; 
  int<lower=1> N_obs_y;
  int<lower=1> N_obs_z;
  int<lower=1> N_items_x;
  int<lower=1> N_items_y;
  int<lower=1> N_items_z;
  int<lower=1> N_id; 
  int likert_x[N_obs_x]; 
  int likert_y[N_obs_y];
  int likert_z[N_obs_z]; 
  int latent_i_x[N_obs_x]; 
  int latent_i_y[N_obs_y];
  int latent_i_z[N_obs_z];
  int item_gndr_i_x[N_obs_x]; 
  int item_gndr_i_y[N_obs_y];
  int item_gndr_i_z[N_obs_z];
  int<lower=2> ncut_x;
  int<lower=2> ncut_y;
  int<lower=2> ncut_z;
  int id[N];
  vector[ncut_y + 1] alpha_yz;
  vector[ncut_x + 1] alpha_x;
}
parameters {
  simplex[ncut_x + 1] pi_x[2*N_items_x];
  simplex[ncut_y + 1] pi_y[2*N_items_y];
  simplex[ncut_z + 1] pi_z[2*N_items_z];
  vector[N] x;
  vector[N] y;
  vector[N] z;
  real beta_xy;
  real beta_zy;
  real<lower=0> sigma_xy;
  real<lower=0> sigma_zy;
  real<lower=0> sd_id_xy;
  vector[N_id] z_id_xy;
  real<lower=0> sd_id_zy;
  vector[N_id] z_id_zy;
}
transformed parameters {
  vector[ncut_x] cutpoints_x[2*N_items_x];
  vector[ncut_y] cutpoints_y[2*N_items_y];
  vector[ncut_z] cutpoints_z[2*N_items_z];
  vector[N_id] r_id_xy = sd_id_xy * z_id_xy;
  vector[N_id] r_id_zy = sd_id_zy * z_id_zy;
  for (n in 1:(2*N_items_x)) {
    cutpoints_x[n] = make_cutpoints(pi_x[n], ncut_x);
  }
  for (n in 1:(2*N_items_y)) {
    cutpoints_y[n] = make_cutpoints(pi_y[n], ncut_y);
  }
  for (n in 1:(2*N_items_z)) {
    cutpoints_z[n] = make_cutpoints(pi_z[n], ncut_z);
  }
}
model {
  // prior model
  for (n in 1:(N_items_x*2)) {  // weakly informative Dirichlet priors for lower Likert responses 
    pi_x[n] ~ dirichlet(alpha_x);
  }
  for (n in 1:(N_items_y*2)) {
    pi_y[n] ~ dirichlet(alpha_yz);
  }
  for (n in 1:(N_items_z*2)) {
    pi_z[n] ~ dirichlet(alpha_yz);
  }
  y ~ normal(0, 1);
  beta_xy ~ normal(0, 0.43);  // 99% prob between -1 and 1, regularized toward zero (null effect)
  beta_zy ~ normal(0, 0.43);
  sigma_xy ~ normal(0, 0.39);  // 99% prob between 0 and 1
  sigma_zy ~ normal(0, 0.39);
  sd_id_xy ~ normal(0, 0.39);
  sd_id_zy ~ normal(0, 0.39);
  z_id_xy ~ std_normal();
  z_id_zy ~ std_normal();

  // latent model
   x ~ normal((beta_xy + r_id_xy[id]) .* y, sigma_xy);
   z ~ normal((beta_zy + r_id_zy[id]) .* y, sigma_zy);

  // observational model
  likert_x ~ ordered_probit(x[latent_i_x], cutpoints_x[item_gndr_i_x]);
  likert_y ~ ordered_probit(y[latent_i_y], cutpoints_y[item_gndr_i_y]);
  likert_z ~ ordered_probit(z[latent_i_z], cutpoints_z[item_gndr_i_z]);
}
generated quantities {
  vector[N_obs_x] pred_x;
  vector[N_obs_y] pred_y;
  vector[N_obs_z] pred_z;
  real sd_x = sd(x);
  real sd_y = sd(y);
  real sd_z = sd(z);
  real mu_x = mean(x);
  real mu_y = mean(y);
  real mu_z = mean(z);
  real beta_xy_std = ((beta_xy / sd_x) * (sd_y));
  real beta_zy_std = ((beta_zy / sd_z) * (sd_y));

  for (n in 1:N_obs_x) {
    pred_x[n] = ordered_probit_rng(x[latent_i_x[n]], cutpoints_x[item_gndr_i_x[n]]);
  }
  for (n in 1:N_obs_y) {
    pred_y[n] = ordered_probit_rng(y[latent_i_y[n]], cutpoints_y[item_gndr_i_y[n]]);
  }
  for (n in 1:N_obs_z) {
    pred_z[n] = ordered_probit_rng(z[latent_i_z[n]], cutpoints_z[item_gndr_i_z[n]]);
  }
}

