Supplementary Materials
Supplement A. Mplus Syntax for the Three-Level Random-Intercept Cross-Lagged Panel Model

This supplement provides the Mplus (Version 8.11) input used to estimate the primary three-level random-intercept cross-lagged panel model (RI-CLPM) reported in the manuscript. The model simultaneously decomposes variance in social jetlag and alcohol use into person-level (stable between-person), burst-level (approximately four-month), and week-level components, and estimates autoregressive and cross-lagged paths at the burst and week levels. It was estimated with Bayesian estimation (two MCMC chains; 20,000 fixed iterations per chain) using data in wide format. Demographic (gender, race/ethnicity) and seasonal (summer vs. other seasons) covariates are included.
Variable key. sj_b#_w# = weekly social jetlag (burst #, week #); alc_b#_w# = weekly alcohol use in total standard drinks (burst #, week #); summer_b#_w1 = seasonal indicator (1 = summer); female, male, white = demographic covariates. Within the model, RI_* are burst-specific random intercepts, *_Bu_* are burst-level latent factors, and *_RI_BS are the between-person random intercepts. A caret (^) denotes a within-level (residual) latent variable used to specify the weekly cross-lagged structure. The TITLE line has been relabeled for clarity; the syntax is otherwise reproduced as estimated.
Mplus input
  TITLE: Three-level RI-CLPM for social jetlag and alcohol use
         (weekly, burst, and between-person levels)
 
  DATA:
    FILE = "wide_jetlag_su.12.8.25.dat";
  VARIABLE:
    ! Full list of variable names
    NAMES =  pid
            sj_b1_w1 sj_b1_w2 sj_b1_w3 sj_b2_w1 sj_b2_w2
     sj_b2_w3 sj_b3_w1 sj_b3_w2
                   sj_b3_w3 alc_b1_w1 alc_b1_w2 alc_b1_w3 alc_b2_w1
                    alc_b2_w2 alc_b2_w3
                   alc_b3_w1 alc_b3_w2 alc_b3_w3  summer_b1_w1 
                   summer_b2_w1 summer_b3_w1 
                    female male white ;
 
    USEVARIABLES = sj_b1_w1 sj_b1_w2 sj_b1_w3 sj_b2_w1 sj_b2_w2
     sj_b2_w3 sj_b3_w1 sj_b3_w2
                   sj_b3_w3 alc_b1_w1 alc_b1_w2 alc_b1_w3 alc_b2_w1
                    alc_b2_w2 alc_b2_w3
                   alc_b3_w1 alc_b3_w2 alc_b3_w3  summer_b1_w1 
                   summer_b2_w1 summer_b3_w1 
                    female male white ;
                    
                    categorical are female male white;
 
 
    MISSING = ALL (-999);
 
    DEFINE:
    ! Create dummy variables for Race
    White = (Race EQ 4);
    ! Create dummy variables for Gender
    female = (Gender EQ 1);
    male = (Gender EQ 2);
 
    ANALYSIS:   MODEL = NOCOV; ! Sets all default covariances to zero
                estimator=bayes;
                process=2;
                FBITERATIONS = 40000;      ! Double from default 10,000
            BITERATIONS = 10000(5000); ! 10,000 iterations, 5,000 burn-in
 
 
 
  MODEL:
 
    ! Random Intercepts for Weekly Variables
    RI_sj_b1 BY sj_b1_w1@1 sj_b1_w2@1 sj_b1_w3@1;
    RI_sj_b2 BY sj_b2_w1@1 sj_b2_w2@1 sj_b2_w3@1;
    RI_sj_b3 BY sj_b3_w1@1 sj_b3_w2@1 sj_b3_w3@1;
 
    RI_alc_b1 BY alc_b1_w1@1 alc_b1_w2@1 alc_b1_w3@1;
    RI_alc_b2 BY alc_b2_w1@1 alc_b2_w2@1 alc_b2_w3@1;
    RI_alc_b3 BY alc_b3_w1@1 alc_b3_w2@1 alc_b3_w3@1;
 
    ! Burst-Level Variance as Latent Variables
    sj_Bu_b1 BY RI_sj_b1@1;
    sj_Bu_b2 BY RI_sj_b2@1;
    sj_Bu_b3 BY RI_sj_b3@1;
    RI_sj_b1@0; RI_sj_b2@0; RI_sj_b3@0;
 
    alc_Bu_b1 BY RI_alc_b1@1;
    alc_Bu_b2 BY RI_alc_b2@1;
    alc_Bu_b3 BY RI_alc_b3@1;
    RI_alc_b1@0; RI_alc_b2@0; RI_alc_b3@0;
 
    ! Between-Subjects Random Intercepts
    sj_RI_BS BY sj_Bu_b1@1 sj_Bu_b2@1 sj_Bu_b3@1;
    alc_RI_BS BY alc_Bu_b1@1 alc_Bu_b2@1 alc_Bu_b3@1;
 
    ! Lagged effects for Burst 1
  sj_b1_w2^ ON sj_b1_w1^ alc_b1_w1^   ;
  sj_b1_w3^ ON sj_b1_w2^ alc_b1_w2^  ;
 
  alc_b1_w2^ ON sj_b1_w1^ alc_b1_w1^ ;
  alc_b1_w3^ ON sj_b1_w2^ alc_b1_w2^   ;
 
  ! Lagged effects for Burst 2
  sj_b2_w2^ ON sj_b2_w1^ alc_b2_w1^  ;
  sj_b2_w3^ ON sj_b2_w2^ alc_b2_w2^  ;
 
  alc_b2_w2^ ON sj_b2_w1^ alc_b2_w1^ ;
  alc_b2_w3^ ON sj_b2_w2^ alc_b2_w2^  ;
 
  ! Lagged effects for Burst 3
  sj_b3_w2^ ON sj_b3_w1^ alc_b3_w1^  ;
  sj_b3_w3^ ON sj_b3_w2^ alc_b3_w2^  ;
 
  alc_b3_w2^ ON sj_b3_w1^ alc_b3_w1^ ;
  alc_b3_w3^ ON sj_b3_w2^ alc_b3_w2^ ;
 
 
  ! Burst-Level Lagged Effects
  sj_Bu_b2 ON sj_Bu_b1  ; ! Constrain autoregressive effects for SJ
  sj_Bu_b3 ON sj_Bu_b2  ;
 
  sj_Bu_b2 ON alc_Bu_b1 ;     ! Leave cross-lagged effects unconstrained
  sj_Bu_b3 ON alc_Bu_b2 ;
 
  alc_Bu_b2 ON alc_Bu_b1 ;! Constrain autoregressive effects for Alcohol
  alc_Bu_b3 ON alc_Bu_b2 ;
 
  alc_Bu_b2 ON sj_Bu_b1 ;       ! Leave cross-lagged effects unconstrained
  alc_Bu_b3 ON sj_Bu_b2 ;
 
 
 
 
  ! covariance between BIs
 
  sj_RI_BS WITH alc_RI_BS;
 
  sj_Bu_b1 WITH alc_Bu_b1;
  sj_Bu_b2 WITH alc_Bu_b2;
  sj_Bu_b3 WITH alc_Bu_b3;
 
    ! Residual Covariances Between Weekly Variables
    sj_b1_w1 WITH alc_b1_w1;
    sj_b1_w2 WITH alc_b1_w2;
    sj_b1_w3 WITH alc_b1_w3;
    sj_b2_w1 WITH alc_b2_w1;
    sj_b2_w2 WITH alc_b2_w2;
    sj_b2_w3 WITH alc_b2_w3;
    sj_b3_w1 WITH alc_b3_w1;
    sj_b3_w2 WITH alc_b3_w2;
    sj_b3_w3 WITH alc_b3_w3;
 
    ! Predict Between-Subjects Variance with Demographics
    sj_RI_BS ON    male female white ;
    alc_RI_BS ON    male female white ;
    [male$1 female$1 white$1];
 
 
! Summer effects on burst-level latent factors
sj_Bu_b1  ON summer_b1_w1;
sj_Bu_b2  ON summer_b2_w1;
sj_Bu_b3  ON summer_b3_w1;
 
alc_Bu_b1 ON summer_b1_w1;
alc_Bu_b2 ON summer_b2_W1;
alc_Bu_b3 ON summer_b3_w1;
 
 
 
  OUTPUT: TECH1 TECH8 STDYX SAMPSTAT CINTERVAL;
 
 
