! The data set "artificial.dat" does not contain the LSAY data
! that was used in the analysis described in the paper. 
! "artificial.dat" contains simulated data with a structure 
! resembling the subset of the LSAY data. 
! The sample size is N=1000, and as in the main analysis of the 
! illustration, there are 7 observed variables and two covariates. 
! The model that generated the data is similar to Model 2 in the 
! paper. It is a 4-class factor mixture model and has a 2-factor 
! model with correlated factors as a within class model. 
! this input file can be run with Mplus 2 or higher, see the
! Analysis command for possible adaptations  


TITLE:  4-class factor mixture model with 2 covariates
    DATA:
! name of the data file
        FILE IS artificial.dat;     
! data have to be raw data (not summary statistics as in multi-group analyses);
        TYPE=INDIVIDUAL;        
    VARIABLE:
! names of the variables in the data file;
        NAMES ARE alg geo qlt bas env bio phy cov1 cov2;   
! number of classes to be estimated;
        CLASSES = c(4);         
    ANALYSIS:
        TYPE = MIXTURE;
! the following feature is new in version 3.01 
! and refers to random starting values
! see MPLUS manual p413-414 for instructions how 
! to modify the number of random starts;
! if you use Mplus 3.01 or higher, you can
! minimize the computation time in an initial run
! by setting start=0 (i.e., no random starts)
! this option is turned off usind the ! -operator such 
! that this input file can be used with older versions of Mplus

!       start=0;  
          
     MODEL:

        %OVERALL%

! the following three lines specify the within class model 
! which is a 2-factor model with correlated factors
       F1 BY alg-qlt bas;   
       F2 BY phy env bio;
       F1 WITH F2;
! the following two commands specify the regression of the two factors 
! on the 2 covariates (path 6 in the paper)
       F1 on cov1 cov2;
       F2 on cov1 cov2;
  
! the following three commands specify the regression of the class variable
!  on the 2 covariates (path 7 in the paper)
  c#1  on  cov1 cov2;
  c#2  on  cov1 cov2;
  c#3  on  cov1 cov2;
 
! VUONG-LO-MENDELL-RUBIN LIKELIHOOD RATIO TEST is computed 
! by deleting the first class
! therefore the restriction of zero factor means in the references class,
! which is necessary to identify the model, has to be specified 
! in any class BUT the first class. If it were specified
! in the first class, deleting the first class would result in a 
! non-identified 3-class model, 
! and the VLMR-test (called aLRT in the article) could not be computed
   %c#4%
! both factor means are fixed to zero in the reference class
! the factor mean of the math factor is fixed to zero for all classes such 
! that all intercepts of the math subscales can be estimated
  [F1@0 F2@0];
! starting values are provided for the math subscales
  [alg-qlt*8 bas*8];
! the following are class specific regressions of the factors on the covariates
   F1 on cov1 cov2;
   F2 on cov1 cov2;

   %c#1%

  [F1@0 F2*.5];
  [alg-qlt*7 bas*7];

   F1 on cov1 cov2;
   F2 on cov1 cov2;

   %c#2%

  [F1@0 F2*1];
  [alg-qlt*9 bas*9];

   F1 on cov1 cov2;
   F2 on cov1 cov2;

   %c#3%

  [F1@0 F2*-1];
  [alg-qlt*6 bas*6];
  
  F1 on cov1 cov2;
  F2 on cov1 cov2;
  
    OUTPUT:
  tech1 tech3 tech11 standardized;