**Missing Not At Random Models for Latent Growth Curve Analyses**

**Mplus Syntax Files**

TITLE:

MAR-based maximum likelihood analysis;

DATA:

file is drugtrial.dat;

VARIABLE:

names are id drug male y1 y2 y3 y4 pattnum;

! id: participant id;

! drug: 0 = placebo, 1 = drug;

! male: 0 = female, 1 = male;

! y1: baseline severity score;

! y2: week 1 severity score;

! y3: week 3 severity score;

! y4: week 6 severity score;

! pattnum: missing data patterns from table 1;

usevariables are drug y1 y2 y3 y4;

missing are all (99);

MODEL:

! quadratic growth model;

! () are parameter labels used in model constraint section;

icept linear quad | y1@0 y2@1 y3@3 y4@6;

y1 - y4 (resvar);

icept (iceptvar);

icept on drug (b3);

linear on drug (b4);

quad on drug (b5);

MODEL CONSTRAINT:

! define new parameters not in the model;

new(meandiff effsize);

! compute endpoint mean difference (equation 9);

meandiff = b3 + 6\*b4 + 36\*b5;

effsize = meandiff / sqrt(iceptvar + resvar);

PLOT:

type is plot3;

series is y1 - y4 (linear);

TITLE:

Diggle and Kenward selection model with survival indicators;

DATA:

file is drugtrial.dat;

VARIABLE:

names are id drug male y1 y2 y3 y4 pattnum;

! id: participant id;

! drug: 0 = placebo, 1 = drug;

! male: 0 = female, 1 = male;

! y1: baseline severity score;

! y2: week 1 severity score;

! y3: week 3 severity score;

! y4: week 6 severity score;

! pattnum: missing data patterns from table 1;

usevariables are drug y1 y2 y3 y4 r3 r4;

missing are all (99);

categorical are r3 r4;

! create survival model indicators, r3 and r4;

DATA MISSING:

names = y2 y3 y4;

type = sdropout;

binary = r3 r4;

ANALYSIS:

estimator = mlr;

integration = montecarlo;

starts = 100 100;

MODEL:

! quadratic growth model;

! () are parameter labels used in model constraint section;

icept linear quad | y1@0 y2@1 y3@3 y4@6;

y1 - y4 (resvar);

icept (iceptvar);

icept on drug (b3);

linear on drug (b4);

quad on drug (b5);

! logistic regressions;

r3 on y2 (logb1);

r3 on y3 (logb2);

r3 on drug (logb3);

r4 on y3 (logb1);

r4 on y4 (logb2);

r4 on drug (logb3);

MODEL CONSTRAINT:

! define new parameters not in the model;

new(meandiff effsize);

! compute endpoint mean difference (equation 9);

meandiff = b3 + 6\*b4 + 36\*b5;

effsize = meandiff / sqrt(iceptvar + resvar);

PLOT:

type is plot3;

series is y1 - y4 (linear);

TITLE:

Wu and Carroll selection (shared parameter) model with survival indicators;

DATA:

file is drugtrial.dat;

VARIABLE:

names are id drug male y1 y2 y3 y4 pattnum;

! id: participant id;

! drug: 0 = placebo, 1 = drug;

! male: 0 = female, 1 = male;

! y1: baseline severity score;

! y2: week 1 severity score;

! y3: week 3 severity score;

! y4: week 6 severity score;

! pattnum: missing data patterns from table 1;

usevariables are drug y1 y2 y3 y4 r3 r4;

categorical are r3 r4;

missing are all (99);

! create survival model indicators, r3 and r4;

DATA MISSING:

names = y2 y3 y4;

type = sdropout;

binary = r3 r4;

ANALYSIS:

estimator = mlr;

integration = montecarlo;

starts = 100 100;

MODEL:

! quadratic growth model;

! () are parameter labels used in model constraint section;

icept linear quad | y1@0 y2@1 y3@3 y4@6;

y1 - y4 (resvar);

icept (iceptvar);

quad@0;

icept on drug (b3);

linear on drug (b4);

quad on drug (b5);

! logistic regressions;

r3 on icept (logb1);

r3 on linear (logb2);

r4 on icept (logb1);

r4 on linear (logb2);

MODEL CONSTRAINT:

! define new parameters not in the model;

new(meandiff effsize);

! compute endpoint mean difference (equation 9);

meandiff = b3 + 6\*b4 + 36\*b5;

effsize = meandiff / sqrt(iceptvar + resvar);

PLOT:

type is plot3;

series is y1 - y4 (linear);

TITLE:

pattern mixture with complete case restriction;

DATA:

file is drugtrial.dat;

VARIABLE:

names are id drug male y1 y2 y3 y4 pattnum;

! id: participant id;

! drug: 0 = placebo, 1 = drug;

! male: 0 = female, 1 = male;

! y1: baseline severity score;

! y2: week 1 severity score;

! y3: week 3 severity score;

! y4: week 6 severity score;

! pattnum: missing data patterns from table 1;

usevariables are drug y1 y2 y3 y4 group;

missing are all (99);

! specify pseudo latent class variable and number of classes;

classes = pattern(3);

! define latent classes with manifest grouping variable;

knownclass = pattern(group = 1 group = 2 group = 3);

DEFINE:

! collapse missing data patterns into grouping variable;

if (pattnum eq 1 or pattnum ge 5) then group = 1;

if (pattnum eq 2) then group = 2;

if (pattnum eq 3 or pattnum eq 4) then group = 3;

ANALYSIS:

type = mixture;

MODEL:

%overall%

! quadratic growth model;

! () are parameter labels used in model constraint section;

icept linear quad | y1@0 y2@1 y3@3 y4@6;

y1 - y4 (resvar);

icept (iceptvar);

icept on drug;

linear on drug;

quad on drug;

! latent variable means used to compute proportions;

[pattern#1] (p1logit);

[pattern#2] (p2logit);

! class-specific models;

%pattern#1%

[icept] (icept1);

[linear] (linear1);

[quad] (quad1);

icept on drug (iondrug1);

linear on drug (londrug1);

quad on drug (qondrug1);

%pattern#2%

[icept] (icept2);

[linear] (linear2);

[quad] (quad2);

icept on drug (iondrug2);

linear on drug (londrug2);

quad on drug (qondrug2);

%pattern#3%

[icept] (icept3);

[linear] (linear3);

[quad] (quad3);

icept on drug (iondrug3);

linear on drug (londrug3);

quad on drug (qondrug3);

MODEL CONSTRAINT:

! implement identifying restrictions;

quad3 = quad1;

qondrug3 = .08;

quad2 < .07;

! define new parameters not in the model;

new(pi1 pi2 pi3 b0 b1 b2 b3 b4 b5 meandiff effsize);

! compute pattern proportions;

pi1 = exp(p1logit)/(exp(0) + exp(p1logit) + exp(p2logit));

pi2 = exp(p2logit)/(exp(0) + exp(p1logit) + exp(p2logit));

pi3 = exp(0)/(exp(0) + exp(p1logit) + exp(p2logit));

! compute average estimates (equation 10);

b0 = pi1\*icept1 + pi2\*icept2 + pi3\*icept3;

b1 = pi1\*linear1 + pi2\*linear2 + pi3\*linear3;

b2 = pi1\*quad1 + pi2\*quad2 + pi3\*quad3;

b3 = pi1\*iondrug1 + pi2\*iondrug2 + pi3\*iondrug3;

b4 = pi1\*londrug1 + pi2\*londrug2 + pi3\*londrug3;

b5 = pi1\*qondrug1 + pi2\*qondrug2 + pi3\*qondrug3;

! compute endpoint mean difference (equation 9);

meandiff = b3 + 6\*b4 + 36\*b5;

effsize = meandiff / sqrt(iceptvar + resvar);

PLOT:

type is plot3;

series is y1 - y4 (linear);

TITLE:

pattern mixture with neighboring case restriction;

DATA:

file is drugtrial.dat;

VARIABLE:

names are id drug male y1 y2 y3 y4 pattnum;

! id: participant id;

! drug: 0 = placebo, 1 = drug;

! male: 0 = female, 1 = male;

! y1: baseline severity score;

! y2: week 1 severity score;

! y3: week 3 severity score;

! y4: week 6 severity score;

! pattnum: missing data patterns from table 1;

usevariables are drug y1 y2 y3 y4 group;

missing are all (99);

! specify pseudo latent class variable and number of classes;

classes = pattern(3);

! define latent classes with manifest grouping variable;

knownclass = pattern(group = 1 group = 2 group = 3);

DEFINE:

! collapse missing data patterns into grouping variable;

if (pattnum eq 1 or pattnum ge 5) then group = 1;

if (pattnum eq 2) then group = 2;

if (pattnum eq 3 or pattnum eq 4) then group = 3;

ANALYSIS:

type = mixture;

MODEL:

%overall%

! quadratic growth model;

! () are parameter labels used in model constraint section;

icept linear quad | y1@0 y2@1 y3@3 y4@6;

y1 - y4 (resvar);

icept (iceptvar);

icept on drug;

linear on drug;

quad on drug;

! latent variable means used to compute proportions;

[pattern#1] (p1logit);

[pattern#2] (p2logit);

! class-specific models;

%pattern#1%

[icept] (icept1);

[linear] (linear1);

[quad] (quad1);

icept on drug (iondrug1);

linear on drug (londrug1);

quad on drug (qondrug1);

%pattern#2%

[icept] (icept2);

[linear] (linear2);

[quad] (quad2);

icept on drug (iondrug2);

linear on drug (londrug2);

quad on drug (qondrug2);

%pattern#3%

[icept] (icept3);

[linear] (linear3);

[quad] (quad3);

icept on drug (iondrug3);

linear on drug (londrug3);

quad on drug (qondrug3);

MODEL CONSTRAINT:

! implement identifying restrictions;

quad3 = quad2;

qondrug3 = qondrug2;

quad2 < .07;

! define new parameters not in the model;

new(pi1 pi2 pi3 b0 b1 b2 b3 b4 b5 meandiff effsize);

! compute pattern proportions;

pi1 = exp(p1logit)/(exp(0) + exp(p1logit) + exp(p2logit));

pi2 = exp(p2logit)/(exp(0) + exp(p1logit) + exp(p2logit));

pi3 = exp(0)/(exp(0) + exp(p1logit) + exp(p2logit));

! compute average estimates (equation 10);

b0 = pi1\*icept1 + pi2\*icept2 + pi3\*icept3;

b1 = pi1\*linear1 + pi2\*linear2 + pi3\*linear3;

b2 = pi1\*quad1 + pi2\*quad2 + pi3\*quad3;

b3 = pi1\*iondrug1 + pi2\*iondrug2 + pi3\*iondrug3;

b4 = pi1\*londrug1 + pi2\*londrug2 + pi3\*londrug3;

b5 = pi1\*qondrug1 + pi2\*qondrug2 + pi3\*qondrug3;

! compute endpoint mean difference (equation 9);

meandiff = b3 + 6\*b4 + 36\*b5;

effsize = meandiff / sqrt(iceptvar + resvar);

PLOT:

type is plot3;

series is y1 - y4 (linear);

TITLE:

pattern mixture with available case restriction;

DATA:

file is drugtrial.dat;

VARIABLE:

names are id drug male y1 y2 y3 y4 pattnum;

! id: participant id;

! drug: 0 = placebo, 1 = drug;

! male: 0 = female, 1 = male;

! y1: baseline severity score;

! y2: week 1 severity score;

! y3: week 3 severity score;

! y4: week 6 severity score;

! pattnum: missing data patterns from table 1;

usevariables are drug y1 y2 y3 y4 group;

missing are all (99);

! specify pseudo latent class variable and number of classes;

classes = pattern(3);

! define latent classes with manifest grouping variable;

knownclass = pattern(group = 1 group = 2 group = 3);

DEFINE:

! collapse missing data patterns into grouping variable;

if (pattnum eq 1 or pattnum ge 5) then group = 1;

if (pattnum eq 2) then group = 2;

if (pattnum eq 3 or pattnum eq 4) then group = 3;

ANALYSIS:

type = mixture;

MODEL:

%overall%

! quadratic growth model;

! () are parameter labels used in model constraint section;

icept linear quad | y1@0 y2@1 y3@3 y4@6;

y1 - y4 (resvar);

icept (iceptvar);

icept on drug;

linear on drug;

quad on drug;

! latent variable means used to compute proportions;

[pattern#1] (p1logit);

[pattern#2] (p2logit);

! class-specific models;

%pattern#1%

[icept] (icept1);

[linear] (linear1);

[quad] (quad1);

icept on drug (iondrug1);

linear on drug (londrug1);

quad on drug (qondrug1);

%pattern#2%

[icept] (icept2);

[linear] (linear2);

[quad] (quad2);

icept on drug (iondrug2);

linear on drug (londrug2);

quad on drug (qondrug2);

%pattern#3%

[icept] (icept3);

[linear] (linear3);

[quad] (quad3);

icept on drug (iondrug3);

linear on drug (londrug3);

quad on drug (qondrug3);

MODEL CONSTRAINT:

! implement identifying restrictions;

quad2 < .07;

quad3 = (336/389)\*quad1 + (53/389)\*quad2;

qondrug3 = (336/389)\*.08 + (53/389)\*qondrug2;

! define new parameters not in the model;

new(pi1 pi2 pi3 b0 b1 b2 b3 b4 b5 meandiff effsize);

! compute pattern proportions;

pi1 = exp(p1logit)/(exp(0) + exp(p1logit) + exp(p2logit));

pi2 = exp(p2logit)/(exp(0) + exp(p1logit) + exp(p2logit));

pi3 = exp(0)/(exp(0) + exp(p1logit) + exp(p2logit));

! compute average estimates (equation 10);

b0 = pi1\*icept1 + pi2\*icept2 + pi3\*icept3;

b1 = pi1\*linear1 + pi2\*linear2 + pi3\*linear3;

b2 = pi1\*quad1 + pi2\*quad2 + pi3\*quad3;

b3 = pi1\*iondrug1 + pi2\*iondrug2 + pi3\*iondrug3;

b4 = pi1\*londrug1 + pi2\*londrug2 + pi3\*londrug3;

b5 = pi1\*qondrug1 + pi2\*qondrug2 + pi3\*qondrug3;

! compute endpoint mean difference (equation 9);

meandiff = b3 + 6\*b4 + 36\*b5;

effsize = meandiff / sqrt(iceptvar + resvar);

PLOT:

type is plot3;

series is y1 - y4 (linear);